Edit Fee - IPFees

Name

Description

Category

Linked Jurisdiction

Referenced Modules

EntitySize (Define EntitySize as LIST w/ DEF=Entity_Large)

ClaimCount (Define ClaimCount as NUMBER w/ DEF=1)

RO_NP (Define RO_NP as BOOLEAN; if PCT RO = national entry jurisdiction w/ DEF=FALSE)

NumberOfWords (Define NumberOfWords as NUMBER w/ DEF=1)

MultipleDependentClaimCount (Define MultipleDependentClaimCount as NUMBER w/ DEF=0)

ISR_AVAILABLE (Define ISR_AVAILABLE (International Search Report) as BOOLEAN w/ DEF=TRUE)

ISA (Define ISA as LIST w/ DEF=ISA_NONE)

EP_VAL_CTY (Define VAL_CTY as MULTILIST w/ DEF=VAL_NONE)

EP_Extension (Define Extension as BOOLEAN w/ DEF=FALSE)

AP_Designations (Define CountryCount as NUMBER w/ DEF=22)

DependentClaimCount (Define DependentClaimCount as NUMBER w/ DEF=0)

OfficeElected (Define OfficeElected as BOOLEAN w/ DEF=FALSE)

ApplicationDate (Define ApplicationDate as DATE w/ DEF=TODAY)

IPRP (IPER) (Define IPRP as LIST w/ DEF=IPRP_NONE)

PriorityCount (Define PriorityCount as NUMBER w/ DEF=0)

IndependentClaimCount (Define IndependentClaimCount as NUMBER w/ DEF=1)

SheetCount (Define SheetCount as NUMBER w/ DEF=10)

Source code associated to referenced modules is parsed along with the fee source code.

Source Code

# File name: PCT-EP-OFF
# File content: Official fees for PCT regional phase: EPO
# Valid until 31/03/2023
RETURN Currency AS 'EUR'
# MODULES: ApplicationDate; ISA; IPRP; SheetCount; ClaimCount; EP_VAL_CTY; EP_Extension

COMPUTE FEE OFF_BasicNationalFee
YIELD 135
ENDCOMPUTE

COMPUTE FEE OFF_DesignationFee
YIELD 660
ENDCOMPUTE

COMPUTE FEE OFF_ExtensionFee OPTIONAL
YIELD 102 IF Extension EQ TRUE
ENDCOMPUTE

COMPUTE FEE OFF_SheetFee
YIELD 17*(SheetCount-35) IF SheetCount GT 35
ENDCOMPUTE

COMPUTE FEE OFF_ClaimFee
LET CF1 AS 265
LET CF2 AS 660
YIELD CF1*(ClaimCount-15) IF ClaimCount GT 15 AND ClaimCount LT 51
YIELD CF2*(ClaimCount-50) + CF1*(ClaimCount-15-(ClaimCount-50)) IF ClaimCount GT 50
ENDCOMPUTE

COMPUTE FEE OFF_SearchFee
LET SF1 AS 1460
LET SF2 AS 1185 #reduction in line with OJ EPO 2022-A2

YIELD 0 IF ISA EQ ISA_EPO
YIELD SF1-SF2 IF ISA EQ ISA_AT OR ISA EQ ISA_FI OR ISA EQ ISA_NPI OR ISA EQ ISA_ES OR ISA EQ ISA_SE OR ISA EQ ISA_TR OR ISA EQ ISA_VI
YIELD SF1 IF ISA NEQ ISA_AT AND ISA NEQ ISA_FI AND ISA NEQ ISA_NPI AND ISA NEQ ISA_ES AND ISA NEQ ISA_SE AND ISA NEQ ISA_TR AND ISA NEQ ISA_VI AND ISA NEQ ISA_NONE
ENDCOMPUTE

COMPUTE FEE OFF_ExaminationFee
LET ExFee1 AS 2055
LET ExFee2 AS 1840
LET Discount AS 0.75

CASE IPRP EQ IPRP_EPO AS # discount scheme if EPO has prepared IPRP (Chapter II)
YIELD ExFee1*Discount IF ISA EQ ISA_EPO 
YIELD ExFee2*Discount IF ISA NEQ ISA_EPO
ENDCASE

CASE IPRP NEQ IPRP_EPO AS # no discount scheme
YIELD ExFee1 IF ISA EQ ISA_EPO
YIELD ExFee2 IF ISA NEQ ISA_EPO
ENDCASE

ENDCOMPUTE

COMPUTE FEE OFF_ValidationFee_CD
YIELD 180 IF VAL_CD IN VAL_CTY
ENDCOMPUTE
COMPUTE FEE OFF_ValidationFee_MA
YIELD 240 IF VAL_MA IN VAL_CTY
ENDCOMPUTE
COMPUTE FEE OFF_ValidationFee_MD
YIELD 200 IF VAL_MD IN VAL_CTY
ENDCOMPUTE
COMPUTE FEE OFF_ValidationFee_TN
YIELD 180 IF VAL_TN IN VAL_CTY
ENDCOMPUTE

# need to check if 3rd annuity is due (>1.5 years after filing date)
COMPUTE FEE OFF_Renewal3
LET RenFee AS 530
LET RenMonth AS ROUND(ApplicationDate!MONTHSTONOW_FROMLASTDAY) #calculate difference in months to today
YIELD RenFee IF RenMonth GTE 18
ENDCOMPUTE

Edit Fee PCT-EP-OFF